Oxygen Multimedia Graphics 22/Oxygen Multimedia Graphics 22.iso/pc/System/OX22/Internal_47_Sway.ls

Text File | 2008-03-12 | 1.6 KB | 54 lines

property mySprite, myAnglePerFrame, myFrameCount, myCounter, myClockwise

on getBehaviorDescription me
  return "SWAY" & RETURN & RETURN & "Rotates a sprite first one way then the other by a given angle per frame." & RETURN & RETURN & "PERMITTED MEMBER TYPES:" & RETURN & "bitmap, Flash, text, vector shape" & RETURN & RETURN & "PARAMETERS:" & RETURN & "* Number of degrees to rotate in each frame" & RETURN & "* Number of frames to move in each direction"
end

on getBehaviorTooltip me
  return "Use with bitmap, Flash, text and vector shape members." & RETURN & RETURN & "Rotates a sprite first one way then the other by a given angle per frame."
end

on beginSprite me
  Initialize(me)
end

on prepareFrame me
  if not myCounter then
    ChangeDirection(me)
  end if
  Turn(me)
end

on Initialize me
  mySprite = sprite(me.spriteNum)
  myCounter = myFrameCount
end

on Turn me
  myCounter = myCounter - 1
  if myClockwise then
    newAngle = mySprite.rotation + myAnglePerFrame
  else
    newAngle = mySprite.rotation - myAnglePerFrame
  end if
  mySprite.rotation = newAngle
end

on ChangeDirection me
  myClockwise = not myClockwise
  myCounter = myFrameCount
end

on isOKToAttach me, aSpriteType, aSpriteNum
  case aSpriteType of
    #graphic:
      return getPos([#bitmap, #flash, #text, #vectorShape], sprite(aSpriteNum).member.type) <> 0
    #script:
      return 0
  end case
end

on getPropertyDescriptionList me
  return [#myAnglePerFrame: [#comment: "Angle to rotate in each frame", #format: #float, #range: [#min: 0, #max: 180], #default: 10], #myFrameCount: [#comment: "Number of frames to move in each direction", #format: #integer, #default: 10]]
end